# PyMOL script for carbonic anhydrase
# jdc 2014_11_01
# carbonic_anhydrase_3D92.pml

# notes on pdb file
# resolution 1.10 A; file contains anisotropic B factors
# alternate conformations: Ile22, Leu47, Asp52, His64,
# Ser152, Ser217, Val223,
load 3D92.pdb, CA

select polypep, resi 4-261
select Zn, resi 262
select CO2-1, resi 301
select CO2-2, resi 302
select His_ligands, resi 94+96+119
select HOH_ligand, resi 401
select Thr199, resi 199
select His64, resi 64
select Glu106, resi 106
select h-phobic, resi 121+143+198+207+209
select cis-peptide-1, resi 29+30
select trans-peptide-1, resi 200+201
select cis-peptide-2, resi 201+202

select glycerol, resn GOL
# GOL303 occupies positions overlapping proton wire
# GOL304 is a surface-bound molecule

select water, resn HOH
disable water

# create distance measurements

distance coord-bond-1, a/262/zn, a/94/ne2
distance coord-bond-2, a/262/zn, a/96/ne2
distance coord-bond-3, a/262/zn, a/119/nd1
distance coord-bond-4, a/262/zn, a/401/o

distance H-bond-1, a/199/og1, a/401/o
distance H-bond-2, a/199/og1, a/106/oe1

# create dihedral angle measurements (cis peptides)
# omega angle for peptide bonds 29-30 (Ser-Pro, cis), 200-201 (His-Pro, trans), 201-202 (Pro-Pro, cis)
dihedral omega29-30, a/29/ca, a/29/c, a/30/n, a/30/ca
dihedral omega200-201, a/200/ca, a/200/c, a/201/n, a/201/ca
dihedral omega201-202, a/201/ca, a/201/c, a/202/n, a/202/ca

# set up coloring schemes and representations for objects and selections

hide everything
util.cbaw polypep
util.cbaw CO2-1
util.cbaw CO2-2
util.cbaw glycerol
set stick_radius=0.2
set sphere_scale=0.3
show sticks, CO2-1
show sticks, CO2-2
show sticks, His_ligands & not(name n+c+o)
show sticks, Thr199 & not(name c+o)
show sticks, His64 & not(name n+c+o)
show sticks, Glu106 & not(name n+c+o)
show sticks, resi 303
show spher, Zn
show nb_sphe, water
show dash, coord-bond-*
show dash, H-bond-*

show spher, HOH_ligand

set cartoon_transparency, 0.5
cartoon dumbbell

set cartoon_highlight_color, grey50
show cartoon, polypep
set cartoon_color, green

# if you like a view in PyMOL, use the "Get View" button
# (right side of upper Tk window), which outputs a view
# matrix like the following to paste in to your script:
set_view (\
-0.887883842, 0.460041642, 0.000409241,\
0.290776104, 0.560510874, 0.775407016,\
0.356500387, 0.688592911, -0.631445229,\
0.000000000, 0.000000000, -63.120868683,\
-6.943085194, -1.513975501, 15.518847466,\
55.354434967, 70.887306213, -20.000000000 )